[VBS] afficher l'animation de copie de fichier

Marsh Posté le 22-11-2005 à 12:35:12

Bonjour,

j'ai un script de copie de fichier tout bete.

mais pendant la copie (qui es assez longue) rien n'est affiché, j'aimerais pouvoir afficher l'animation standart de copie de windows

est-ce possible ?

sinon il me reste cette solution, mais c'est moins "elegant"
http://www.microsoft.com/technet/s [...] y0316.mspx

merci

Artic

Message édité par artic_planet le 22-11-2005 à 16:44:46

Reply

Marsh Posté le 22-11-2005 à 12:35:12

Reply

Marsh Posté le 22-11-2005 à 14:04:23

Bonjour,

A ma connaissance NON. Tu peux par contre utiliser la bidouille avec InternetExplorer.Application avec un gif anime ?

Reply

Marsh Posté le 22-11-2005 à 16:44:11

voici donc mon script final, pour ceux que ça interesse

ça copie le dossier dossier_source dans un dossier se trouvant dans dossier_dest et portant le nom de la date du jour ainsi que l'heure courante.

le script affiche une petite fenetre pendant la copie.

' ################## DONNEES
dossier_source = "c:\acopier"
dossier_dest = "D:\"

On Error Resume Next
'Wscript.Echo "Début du script"

' ################## CREER LE REPERTOIRE
Set fso = WScript.CreateObject("Scripting.FileSystemObject" )
strDate = Year(Now) & "-" & Right("0" & Month(Now),2) & "-" & Right("0" & Day(Now),2) & " "
strDate = strDate & Right("0" & Hour(Now),2) & "-" & Right("0" & Minute(Now),2) & "-" & Right("0" & Second(Now),2)
fso.CreateFolder(dossier_dest & strDate)

' ################## AFFICHER UNE FENETRE D'INFORMATION
strComputer = "."
Set objWMIService = GetObject("Winmgmts:\\" & strComputer & "\root\cimv2" )
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor" )
For Each objItem in colItems
intHorizontal = objItem.ScreenWidth
intVertical = objItem.ScreenHeight
Next

Set objExplorer = CreateObject _
("InternetExplorer.Application" )

objExplorer.Navigate "about:blank"
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Left = (intHorizontal - 400) / 2
objExplorer.Top = (intVertical - 100) / 2
objExplorer.Width = 400
objExplorer.Height = 100
objExplorer.Visible = 1

objExplorer.Document.Body.Style.Cursor = "wait"

objExplorer.Document.Title = "Copie de " & dossier_source
objExplorer.Document.Body.InnerHTML = "<div align=center><font face=arial><b>Copie en cours, merci de patienter.</b></font></div>"

' ################## COPIER LE REPERTOIRE
fso.CopyFolder dossier_source , dossier_dest & strDate, true

' ################## FREMER LA FENETRE
objExplorer.Document.Body.Style.Cursor = "default"
objExplorer.Quit

Wscript.Echo "Copie terminée"

Reply

[VBS] afficher l'animation de copie de fichier - [résolu]

Sujets relatifs:

Leave a Replay