[RESOLU] mail auto s'affiche bien mais ne s'envoie pas

mail auto s'affiche bien mais ne s'envoie pas [RESOLU] - VB/VBA/VBS - Programmation

Marsh Posté le 20-01-2023 à 23:13:50    

Bonjour,
 
3 jours que je suis dessus, là je craque.
J'essaye d'envoyer un mail automatiquement depuis Excel.
ce que je ne comprends pas c'est que la méthode display fonctionne, mais pas la send, et l'idée c'est que justement cela s'envoie tout seul...
ci dessous le code.
 

Code :
  1. Sub envoimail2()
  3. Dim CeFichier As String
  4. CeFichier = ThisWorkbook.Name
  6. Dim oOutlook As Object
  7. Set oOutlook = CreateObject("Outlook.Application" )
  8. Dim oMail As Object
  9. Set oMail = oOutlook.CreateItem(0)
  10. Dim oObjetWord As Object
  11. Set oObjetWord = oMail.GetInspector.WordEditor
  13. With oMail
  14.     .To = Workbooks(CeFichier).Worksheets("surveillance" ).Range("K2" )
  15.     .Subject = Workbooks(CeFichier).Worksheets("surveillance" ).Range("K4" )
  16. 'ca, ca marche, mais il me faut envoyer un tableau
  17. '    .Body = Workbooks(CeFichier).Worksheets("surveillance" ).Range("C2" )
  18. '    .Send
  19. 'ca, ca marche aussi mais c'est display
  20. '     Workbooks(CeFichier).Worksheets("surveillance" ).Range("C2:F3" ).Copy
  21. '    oObjetWord.Range(0).Paste
  22. '    .Display
  23. 'ca, ca ne marche pas, ca bloque sur .send avec Erreur 5
  24. 'argument ou appel de procédure incorrect
  25.      Workbooks(CeFichier).Worksheets("surveillance" ).Range("C2:F3" ).Copy
  26.      oObjetWord.Range(0).Paste
  27.     .Send
  28.    
  29. End With


 
Vous auriez des pistes?


Message édité par wago le 22-01-2023 à 22:20:56
Reply

Marsh Posté le 20-01-2023 à 23:13:50   

Reply

Marsh Posté le 22-01-2023 à 20:17:01    

Alors solution trouvée, et c'était clairement pas si simple, un grand merci à BrunoM45 du forum developpez.net:
 
 

Code :
  1. Option Explicit
  3. ' Forum : https://www.developpez.net/forums/d [...] -vba-excel
  4. ' https://www.developpez.net/forums/u20954/brunom45/
  6. ' Constante type d'élément Outlook (pour le late binding)
  7. Const olMailItem As Integer = 0
  8. ' Constantes Formats de l'email
  9. Const olFormatHTML As Integer = 2
  11. ' Ce code permet d'intégrer une plage donnée dans le corps d'un mail
  12. Private Sub EnvoiMailAvecImg()
  13.   Dim OutApp As Object, OutMail As Object
  14.   Dim RngAcopier As Range
  15.   Dim StrHTML As String
  16.  
  17.   ' Définir la plage des cellules à envoyer
  18.   Set RngAcopier = ThisWorkbook.Sheets("surveillance" ).Range("C2:F3" )
  19.   ' Avec l'application
  20.   With Application
  21.     .EnableEvents = False ' Désactiver les évènements
  22.     .ScreenUpdating = False ' Désactiver le rafraichissement
  23.   End With
  24.   ' Créer une instance Outllok et Mail
  25.   Set OutApp = CreateObject("Outlook.Application" )
  26.   Set OutMail = OutApp.CreateItem(olMailItem)
  27.   With OutMail
  28.     .BodyFormat = olFormatHTML  ' Format HTML
  29.     .To = ThisWorkbook.Worksheets("surveillance" ).Range("K2" )
  30.     '.CC = "LaCopie@fai.fr"
  31.     '.BCC = "LaCopieCachee@fai.fr"
  32.     .Subject = ThisWorkbook.Worksheets("surveillance" ).Range("K4" )
  33.     StrHTML = "Bonjour, <br>" & "Vous trouverez ci-dessous le tableau"
  34.     .HTMLBody = StrHTML & RangetoHTML(RngAcopier)
  35.     .Send   'or use .Display
  36.   End With
  37.   With Application
  38.     .EnableEvents = True
  39.     .ScreenUpdating = True
  40.   End With
  41.   ' Effacer les variables objet
  42.   Set RngAcopier = Nothing: Set OutMail = Nothing: Set OutApp = Nothing
  43. End Sub
  45. Function RangetoHTML(Rng As Range)
  46.   Dim Fso As Object, Ts As Object
  47.   Dim TempFile As String
  48.   Dim TempWs As Worksheet
  49.   ' Créer le nom du fichier
  50.   TempFile = Environ$("temp" ) & "\" & Format(Now, "dd-mm-yy h-mm-ss" ) & ".htm"
  51.   ' Désactiver le rafraichissement ici aussi
  52.   Application.ScreenUpdating = False
  53.   ' Copier la plage et créer un classeur pour coller les données dedans
  54.   Set TempWs = ThisWorkbook.Worksheets.Add
  55.   Rng.Copy
  56.   With TempWs
  57.     With .Range(Rng.Address)
  58.       .PasteSpecial Paste:=8
  59.       .PasteSpecial xlPasteValues, , False, False
  60.       .PasteSpecial xlPasteFormats, , False, False
  61.     End With
  62.     Application.CutCopyMode = False
  63.     On Error Resume Next
  64.     .DrawingObjects.Visible = True
  65.     .DrawingObjects.Delete
  66.     On Error GoTo 0
  67.   End With
  68.   ' Publier la feuille dans un fichier HTML
  69.   With ThisWorkbook.PublishObjects.Add(SourceType:=xlSourceRange, _
  70.     Filename:=TempFile, Sheet:=TempWs.Name, Source:=Rng.Address, HtmlType:=xlHtmlStatic)
  71.     .Publish (True)
  72.   End With
  73.   ' Lire les données du fichier
  74.   Set Fso = CreateObject("Scripting.FileSystemObject" )
  75.   Set Ts = Fso.GetFile(TempFile).OpenAsTextStream(1, -2)
  76.   RangetoHTML = Ts.readall
  77.   Ts.Close
  78.   RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
  79.     "align=left x:publishsource=" )
  80.   ' supprimer la feuille
  81.   Application.DisplayAlerts = False
  82.   TempWs.Delete
  83.   Application.DisplayAlerts = True
  84.   ' Supprimer le fichier HTML
  85.   Kill TempFile
  86.   ' Effacer les variables objet
  87.   Set Ts = Nothing: Set Fso = Nothing: Set TempWs = Nothing
  88. End Function

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed