Aide modification d'un batch pour la carte reseau

Aide modification d'un batch pour la carte reseau - Shell/Batch - Programmation

Marsh Posté le 13-03-2025 à 08:01:24    

Hello j'ai créer un point batch assez simple pour basculer d'un réseau a un autre simplement tout fonctionne bien mais voila maintenant j'aurais besoin de le faire évoluer car il se base sur le nom de la carte réseau hors en fonction d'ou je suis j'ai pas forcement le même adaptateur ( et donc le nom de carte réseau change) jusque la je changeait a chaque fois mais je voulais comment faire pour qu'un seul script gère les deux en fonction de la carte active? actuellement j'ai ceci mais il me faut soit le modifier soit deux script pour basculer a chaque fois de LAN a LAN 2 je me doute qu'il y a plsu simple mais je ne vois pas comment.
 

Code :
  1. @echo off
  2. set carte="LAN"
  3. set adrfixe=192.168.1.65
  4. set masque=255.255.255.0
  6. set carte2="LAN"
  7. set adrfixe2=10.0.10.3
  8. set masque2=255.0.0.0
  10. set carte3="LAN"
  11. set adrfixe3=192.168.168.65
  12. set masque3=255.255.255.0
  14. set carte4="LAN"
  15. set adrfixe4=10.1.10.11
  16. set masque4=255.0.0.0
  17. set passerelle4=10.1.10.12
  19. set carte5="LAN"
  20. set adrfixe5=192.168.0.11
  21. set masque5=255.255.255.240
  22. set passerelle5=192.168.0.1
  24. set carte6="LAN"
  25. set adrfixe6=172.31.255.100
  26. set masque6=255.255.255.0
  27. set passerelle6=172.31.255.1
  29. set carte7="LAN"
  30. set adrfixe7=192.168.1.10
  31. set masque7=255.255.255.0
  32. set passerelle7=192.168.1.1
  33. set dns=8.8.8.8
  35. set carte8="LAN"
  36. set adrfixe8=192.0.2.11
  37. set masque8=255.255.255.0
  38. set passerelle8=192.0.2.1
  43. :question
  44. SET /P lan=Adressage IP   1/ DCHP    2/ 192.168.1.65     3/ 10.0.10.3    4/ 192.168.168.65    5/ 10.1.10.11     6/ 192.168.0.11  7/ 172.31.255.100  8/192.168.1.10 9/192.0.2.11 10/ QUITTER (1/2/3/4/5/6/7/8/9)? :
  45. if %lan%==1 goto IPDHCP
  46. if %lan%==2 goto IPfixe
  47. if %lan%==3 goto IPfixe2
  48. if %lan%==4 goto IPfixe3
  49. if %lan%==5 goto IPfixe4
  50. if %lan%==6 goto IPfixe5
  51. if %lan%==7 goto IPfixe6
  52. if %lan%==8 goto IPfixe7
  53. if %lan%==9 goto IPfixe8
  54. if %lan%==10 goto Nfin
  56. goto question
  58. :IPfixe8
  59. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe8% (O/N)? :
  60. if %lan%==o goto OKFixe8
  61. if %lan%==O goto OKFixe8
  62. if %lan%==n goto Nfin
  63. if %lan%==N goto Nfin
  64. goto IPfixe8
  66. :IPfixe7
  67. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe7% (O/N)? :
  68. if %lan%==o goto OKFixe7
  69. if %lan%==O goto OKFixe7
  70. if %lan%==n goto Nfin
  71. if %lan%==N goto Nfin
  72. goto IPfixe7
  74. :IPfixe6
  75. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe6% (O/N)? :
  76. if %lan%==o goto OKFixe6
  77. if %lan%==O goto OKFixe6
  78. if %lan%==n goto Nfin
  79. if %lan%==N goto Nfin
  80. goto IPfixe6
  82. :IPfixe5
  83. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe5% (O/N)? :
  84. if %lan%==o goto OKFixe5
  85. if %lan%==O goto OKFixe5
  86. if %lan%==n goto Nfin
  87. if %lan%==N goto Nfin
  88. goto IPfixe5
  90. :IPfixe4
  91. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe4% (O/N)? :
  92. if %lan%==o goto OKFixe4
  93. if %lan%==O goto OKFixe4
  94. if %lan%==n goto Nfin
  95. if %lan%==N goto Nfin
  96. goto IPfixe4
  98. :IPfixe3
  99. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe3% (O/N)? :
  100. if %lan%==o goto OKFixe3
  101. if %lan%==O goto OKFixe3
  102. if %lan%==n goto Nfin
  103. if %lan%==N goto Nfin
  104. goto IPfixe3
  106. :IPfixe2
  107. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe2% (O/N)? :
  108. if %lan%==o goto OKFixe2
  109. if %lan%==O goto OKFixe2
  110. if %lan%==n goto Nfin
  111. if %lan%==N goto Nfin
  112. goto IPfixe2
  115. :IPfixe
  116. SET /P lan=confirmer l'adressage en IP Fixe %adrfixe% (O/N)? :
  117. if %lan%==o goto OKFixe
  118. if %lan%==O goto OKFixe
  119. if %lan%==n goto Nfin
  120. if %lan%==N goto Nfin
  121. goto IPfixe
  124. :OKFixe
  125. netsh interface ipv4 set address %carte% static %adrfixe% %masque% 
  126. netsh inter ipv4 delete dnsservers LAN all > nul
  130. goto Ofin
  132. :OKFixe2
  133. netsh interface ip set address %carte2% static %adrfixe2% %masque2% 
  134. netsh inter ip delete dnsservers LAN all > nul
  138. goto Ofin
  141. :OKFixe3
  142. netsh interface ip set address %carte3% static %adrfixe3% %masque3% 
  143. netsh inter ip delete dnsservers LAN all > nul
  147. goto Ofin
  149. :OKFixe4
  150. netsh interface ip set address %carte4% static %adrfixe4% %masque4% %passerelle4%
  151. netsh inter ip delete dnsservers LAN all > nul
  155. goto Ofin
  157. :OKFixe5
  158. netsh interface ip set address %carte5% static %adrfixe5% %masque5% %passerelle5%
  159. netsh inter ip delete dnsservers LAN all > nul
  163. goto Ofin
  166. :OKFixe6
  167. netsh interface ip set address %carte6% static %adrfixe6% %masque6% %passerelle6%
  168. netsh inter ip delete dnsservers LAN all > nul
  172. goto Ofin
  175. :OKFixe7
  176. netsh interface ip set address %carte7% static %adrfixe7% %masque7% %passerelle7%
  177. netsh interface ip set address %carte7% dns %dns%
  180. goto Ofin
  183. :OKFixe8
  184. netsh interface ip set address %carte8% static %adrfixe8% %masque8% %passerelle8%
  185. netsh interface ip set address %carte8% dns %dns%
  189. goto Ofin
  192. :IPDHCP
  193. SET /P lan=confirmer l'adressage en IP Dynamique (O/N)? :
  194. if %lan%==o goto OKDHCP
  195. if %lan%==O goto OKDHCP
  196. if %lan%==n goto Nfin
  197. if %lan%==N goto Nfin
  198. goto IPDHCP
  200. :OKDHCP
  201. netsh interface ip set address %carte% dhcp
  202. netsh inter ip delete dnsservers LAN all > nul
  203. netsh inter ip set dnsservers LAN dhcp > nul
  204. goto Ofin
  206. :Nfin
  207. @echo Aucune modification n'a ete appliquee
  208. @echo -
  209. SET /P lan=appuyez sur [ENTREE] pour quitter
  210. goto fin
  212. :Ofin
  213. @echo La nouvelle configuration vient d'etre appliquee
  214. @echo -
  215. SET /P lan=appuyer sur [ENTREE] pour quitter
  216. goto fin
  218. :fin

Reply

Marsh Posté le 13-03-2025 à 08:01:24   

Reply

Marsh Posté le 15-04-2025 à 06:29:31    

Bonjour,
Voilà une version épurée de ton script, avec une ligne au début pour récupérer le nom du réseau :

Code :
  1. @echo off
  2. setlocal enableextensions enabledelayedexpansion
  3. ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
  4. color 0A
  6. for /f "tokens=2 delims==" %%A in ('WMIC NIC WHERE ^(NetEnabled^=TRUE AND GUID is not Null^) GET NetConnectionID /FORMAT:LIST ^| findstr .') do if not defined carte set "carte=%%A"
  7. if not defined carte (exit /b 1)
  9. set static1=192.168.1.65;255.255.255.0;;;
  10. set static2=10.0.10.3;255.0.0.0;;;
  11. set static3=192.168.168.65;255.255.255.0;;;
  12. set static4=10.1.10.11;255.0.0.0;10.1.10.12;;
  13. set static5=192.168.0.11;255.255.255.240;192.168.0.1;;
  14. set static6=172.31.255.100;255.255.255.0;172.31.255.1;;
  15. set static7=192.168.1.10;255.255.255.0;192.168.1.1;8.8.8.8;
  16. set static8=192.0.2.11;255.255.255.0;192.0.2.1;;
  18. :question
  20. cls
  21. echo.-------------------------------------------------------------
  22. echo.---------- CARTE RESEAU : "%carte%"
  23. echo.-------------------------------------------------------------
  24. set "lan="
  25. set /p lan="Adressage IP   0/ DCHP    1/ 192.168.1.65     2/ 10.0.10.3    3/ 192.168.168.65    4/ 10.1.10.11     5/ 192.168.0.11  6/ 172.31.255.100  7/192.168.1.10 8/192.0.2.11 9/ QUITTER (0/1/2/3/4/5/6/7/8/9)? : "
  26. if not defined lan (goto question)
  27. timeout /t 1 /nobreak >nul
  28. echo.
  30. if "%lan%"=="9" (goto Nfin)
  31. if "%lan%"=="0" (
  32. set "val="
  33. set /p val="confirmer l'adressage en IP Dynamique (O/N)? : "
  34. if /i "!val!"=="O" (goto OKDHCP) else (goto question)
  35. )
  37. call :configuration "!static%lan%!" && goto Ofin
  39. goto question
  41. :configuration
  43. for /f "tokens=1-4 delims=;" %%A in ("%~1" ) do (
  44. set "address=%%~A"
  45. set "mask=%%~B"
  46. set "gateway=%%~C"
  47. set "dns=%%~D"
  48. )
  50. set "conf="
  51. set /p conf="confirmer l'adressage en IP Fixe "!address!" (O/N)? : "
  52. if not "%conf%"=="O" (exit /b 1)
  54. netsh int ipv4 set address %carte% static !address! !mask! !gateway!
  55. if defined dns (netsh int ipv4 set dnsservers "%carte%" static !dns! no) else (netsh int ipv4 delete dnsservers "%carte%" all >nul)
  56.                                                                                                                        
  57. exit /b 0
  59. :OKDHCP
  60. netsh int ipv4 set address %carte% dhcp
  61. netsh int ipv4 delete dnsservers %carte% all >nul
  62. netsh int ipv4 set dnsservers %carte% dhcp >nul
  64. :Ofin
  65. echo.
  66. @echo La nouvelle configuration vient d'etre appliquee
  67. @echo -
  68. SET /P quit=appuyer sur [ENTREE] pour quitter
  69. exit
  71. :Nfin
  72. echo.
  73. @echo Aucune modification n'a ete appliquee
  74. @echo -
  75. SET /P quit=appuyez sur [ENTREE] pour quitter
  76. exit

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed