Synthèse vocale ou le narrateur

Synthèse vocale ou le narrateur - Win 10 - Windows & Software

Marsh Posté le 04-07-2020 à 18:13:31    

Bonjour,
Comment enregistrer sur fichier audio ce que dit le narrateur ?
 
J'ai une solution décrite ici
https://stackoverflow.com/questions [...] n-vbscript
mais j'aimerais une méthode plus universelle.
Merci

Reply

Marsh Posté le 04-07-2020 à 18:13:31   

Reply

Marsh Posté le 06-07-2020 à 17:29:58    

Code :
  1. dim scrFName, clArgs
  2. scrFName = Wscript.ScriptFullName
  3. set clArgs = Wscript.Arguments
  5. Set fso = CreateObject("Scripting.FileSystemObject" )
  7. dim intxt, outwav
  8. if clArgs.Count > 1 then
  9.   intxt = clArgs(0)
  10.   outwav = clArgs(1)
  11. elseif  clArgs.Count > 0 then
  12.   intxt = clArgs(0)
  13.   outwav = ""
  14. else
  15.   Wscript.Echo "usage : " _
  16.    & fso.GetFileName(scrFName) _
  17.    & " input.txt [output.wav]" & vbCrLf
  18.   Wscript.quit
  19. end if
  21. if fso.FileExists(intxt) then
  22.   if fso.GetParentFolderName(intxt) = "" then
  23.     intxt = fso.GetAbsolutePathName(intxt)
  24.   end if
  25.   if outwav = "" then
  26.     outwav = fso.GetParentFolderName(intxt) & "\" _
  27.     & fso.GetBaseName(intxt) & ".wav"
  28.   end if
  29. else
  30.   Wscript.Echo "Input file not found: " & intxt
  31.   Wscript.quit
  32. end if
  34. dim intxtcontent
  35. set f = fso.OpenTextFile(intxt, 1)
  36. intxtcontent = f.ReadAll
  37. f.close
  38. set f = nothing
  40. Const SAFT48kHz16BitStereo = 39
  41. Const SSFMCreateForWrite = 3
  43. set sapiFStream = CreateObject("SAPI.SpFileStream" )
  44. sapiFStream.Format.Type = SAFT48kHz16BitStereo
  45. call sapiFStream.Open(outwav, SSFMCreateForWrite)
  46. set sapiVoice = CreateObject("SAPI.SpVoice" )
  47. Set sapiVoice.AudioOutputStream = sapiFStream
  48. 'sapiVoice.Rate = -2 ' from -10 to 10
  49. sapiVoice.Speak(intxtcontent)
  50. sapiFStream.Close
  51. set sapiVoice = nothing
  52. set sapiFStream = nothing
  54. set fso = nothing


Un petit script assez complet. Ça fonctionne super bien  :sol:  
Il suffit de glisser un fichier texte sur le .vbs qui contient ce code et il génère un fichier .wav tout seul  :jap:  
Ou alors vous l'appelez en ligne de commande avec deux paramètres, le fichier d'entrée (txt) et celui de sortie (wav).
 
Maintenant, c'est du vbscript et du SAPI, et, si j'ai bien compris, deux technologies qui ont leur âge.
Surtout le vbscript et ses +25 ans  :ouch:  
Une suggestion pour utiliser une tech plus récentes, ou Microsoft va continuer à supporter les scripts et les COM sous-jacents ad-vitam ? (et aussi simple que ce script aussi)

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed