partage d'imprimante domaine active directory.

partage d'imprimante domaine active directory. - Windows & Software

Marsh Posté le 07-05-2004 à 09:52:28    

voilà le ou les soucis.
 
le premier soucis est que je n'ai rien d'un administrateur mais que ma boite a accepté des contrat qui me pousse à me conduire comme tel. me voilà donc en charge d'un domaine active directorie avec son serveur windows 2000 et 15 poste windows 2000 et 300 compte repertorié sur le serveur.
 
 
mon probleme concerne le partage d'imprimante. sur un réseau en workgroup avec un utilisateur par poste, pas de soucis pour les partage, mais là, si je conecte une imprimante réseau, elle n'est disponible que sur le compte et l'ordinateur ou je l'ai créé.
 
 
je voudrait savoir comment faire que chacun des 300 utilisateurs puisse imprimer à partir de n'importe quel poste sur l'imprimante partagé par le serveur.
 
pour l'instant la seul solution que j'ai trouvé serais de loguer les 300 compte sur chaque poste et à chaque fois de conecter l'imprimante. rassurer vous je n'éssayerait même pas. ceci dit une vrai solution me soulagerait.
 
 
 merci d'avance. :hello:


---------------
P.C. ça veut pas forçément dire Petit Con
Reply

Marsh Posté le 07-05-2004 à 09:52:28   

Reply

Marsh Posté le 07-05-2004 à 12:15:53    

si tu n'a que 15 postes tu peux installer l'imprimante en dur en creant un port tcp/ip avec le compte admin, la l'imprimante sera disponible quel que soit l'utilisateur logué.
la meilleur methode serait de faire un script pour connecter l'imprimante et qui s'execute au logon de tes users, tres simple avec AD et de cette facon tu t'assure que l'imprimante est bien connectée a chaque reboot.

Reply

Marsh Posté le 07-05-2004 à 12:23:10    

Sinon ya le profil par defaut, c'est bien pratique http://support.microsoft.com/defau [...] ;fr;305709
 
L'imprimante configuré dans le profil par defaut sera disponible pour tous les nouveaux compte qui se connectera sur le poste en question.
 
 
Mais sinon un script au logon pour ajotuer les imprimantes c'est pas mal


---------------
Cherche geekette | Traquez vos billets d'€ | Don du sang | Don de moelle osseuse
Reply

Marsh Posté le 07-05-2004 à 13:00:41    

1) Installer ton imprimante sur le serveur d'impression (ton 2000 server typiquement)
2) Mettre un script de connexion (idéalement via une GPO) pour qu'elle soit connectée au login de l'utilisateur
 
Voici par exemple un tel script (écrit en VBScript), je n'ai pas défini d'imprimante par défaut, mais celà peut se faire à l'aide de l'objet WScript.Network.SetDefaultPrinter (donc wshNetwork.SetDefaultPrinter "\\monserveur\monimprimante" ):
 

Code :
  1. Option Explicit
  2. On Error Resume Next
  4. Dim wshNetwork, wshShell, wshSysEnv, colDrives, nReturnCode
  5. Dim i, j
  6. Dim aryDrives, aryShares, strUser
  7. Dim colPrinters, aryPrinters
  9. Dim BS
  10. BS = Chr(92) ' Set a backslash (\)
  12. Set wshNetwork = WScript.CreateObject("WScript.Network" )
  13. Set wshShell = WScript.CreateObject("WScript.Shell" )
  14. Set wshSysEnv = wshShell.Environment("SYSTEM" )
  15. strUser = wshShell.ExpandEnvironmentStrings("%USERNAME%" )
  17. ' Those array are linked, using two 1-dim arrays instead of one 2-dim array
  18. aryDrives = Array("F:", "M:", "O:", "U:" )
  19. aryShares = Array("\\monserveur\metro$", _
  20.                   "\\monserveur\partage$\" & strUser & "\mes documents", _
  21.                   "\\monserveur\partage$\" & strUser & "\outlook", _
  22.                   "\\monserveur\partage$" )
  24. aryPrinters = Array("\\monserveur\infoprint", _
  25.                     "\\monserveur\bobcolpt1-p", _
  26.                     "\\monserveur\bobcolpt1-l", _
  27.                     "\\monserveur\bobcobac-l" )
  30. If (wshSysEnv("OS" ) = "Windows_NT" ) Then
  31.  
  32.    ' Connect drives
  33.    Set colDrives = wshNetwork.EnumNetworkDrives
  34.    For i = 0 To colDrives.Count - 1 Step 2
  35.       ' Disconnect previous connections
  36.       For j = LBound(aryDrives) To UBound(aryDrives)
  37.          If (colDrives(i) = aryDrives(j)) Then
  38.             wshNetwork.RemoveNetworkDrive aryDrives(j)
  39.          End If
  40.       Next
  41.    Next
  42.    ' Map new drive
  43.    If UBound(aryDrives) = UBound(aryShares) Then
  44.       For i = Lbound(aryDrives) To UBound(aryDrives)
  45.          wshNetwork.MapNetworkDrive aryDrives(i), aryShares(i)
  46.       Next
  47.    Else
  48.       MsgBox "Error into connexion's script, aryShares and arryDrives aren't of the same size !"
  49.    End If
  50.    
  51.    ' Connect printers
  52.    Set colPrinters = wshNetwork.EnumPrinterConnections
  53.    For i = 0 To colPrinters.Count - 1 Step 2
  54.       ' Disconnect already connected printers
  55.       For j = LBound(aryPrinters) To UBound(aryPrinters)
  56.          If (colPrinters(i) = aryPrinters(j)) Then
  57.             wshNetwork.RemovePrinterConnection aryPrinters(j)
  58.          End If
  59.       Next
  60.    Next
  61.    For j = LBound(aryPrinters) To UBound(aryPrinters)
  62.       wshNetwork.AddWindowsPrinterConnection aryPrinters(j)
  63.    Next
  64. Else
  65.    WScript.Echo "This WSH logon script supports only Windows NT/2000/XP/2003." & vbNewLine &_
  66.                 "Exiting..."
  67.    Set wshNetwork = Nothing
  68.    Set wshShell = Nothing
  69.    WScript.Quit(1)
  70. End If
  72. Set wshNetwork = Nothing
  73. Set wshShell = Nothing
  74. WScript.Quit(nReturnCode)


 
Ces scripts sont assez souples, tu peux aller sur http://msdn.microsoft.com/scripting/ pour aller cehrcher la doc et référence du langage. Il existe aussi sur Technet le "Microsoft Script Center" avec pas mal d'exemples de scripts)


Message édité par Requin le 07-05-2004 à 13:05:47
Reply

Marsh Posté le 17-05-2004 à 18:58:57    

di moi " hp_nar"  ta boite ne chercherait pas des administrateurs par hasard ? ou assistant, je cherche du boulot, alors on sait jamé.
merci

Reply

Marsh Posté le 17-05-2004 à 19:05:00    

teamm : pour etre deux dans la galère à poster sur Software et réseaux ?
 
 
:lol:


---------------
Cherche geekette | Traquez vos billets d'€ | Don du sang | Don de moelle osseuse
Reply

Marsh Posté le 17-05-2004 à 20:25:08    

tu c comme ca on s'entraidera, ya pa de mal à galerer. !!!!!!!!!!!!!!!!!!!! tu as de l'humour k meme!!!!!!!!!!!!

Reply

Marsh Posté le 25-05-2004 à 10:34:55    

salut tout le monde désolé pour le temp de réponse mais j'étais occupé sur d'autre chantiers ces derniers temps et celui ci m'était un peu sorti de la tête.
 
pour finir j'ai utilisé la solution d'installer sur chaque poste l'imprimente en définissant un port TCP/IP
 
ça marche nickel. merci à tous pour le temps passé à me répondre. :hello:


---------------
P.C. ça veut pas forçément dire Petit Con
Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed