automatiser un effacement de fichiers ?

Marsh Posté le 15-06-2006 à 11:31:29

bonjour,

j'ai une question à vous soumettre :

situation : un serveur windows 2003 avec un partage de repertoire que les utilisateurs utilisent pour
mettre leurs fichiers "en vrac"

comme c'est un serveur il n'est pas censé etre utilisé par quelqu'un (pas d'ouverture de session tous les jours quoi...)

et ce que je cherche , c'est un moyen d'automatiser un nettoyage de ce fameux repertoire.

Y aurait-il une procédure qui puisse se lancer automatiquement et régulièrement
pour supprimer les fichiers ayant été créés depuis plus de N jours?

merci d'avance pour vos propositions. :hello:

Message cité 1 fois

Reply

Marsh Posté le 15-06-2006 à 11:31:29

Reply

Marsh Posté le 15-06-2006 à 11:36:27

tu fais un script (*vbs ou bat) et tu utilise la planificateur de tâche :

Message cité 1 fois

Reply

Marsh Posté le 15-06-2006 à 12:30:39

cvb a écrit :

tu fais un script (*vbs ou bat) et tu utilise la planificateur de tâche :

merci pour ta réponse. Je crois que c'est aussi le plus simple. j'y avait déjà pensé, mais je voulais d'autres avis pour comparer.

Par contre, j'ai encore besoin de vous car le vbs je ne connais pas et les batchs je connais mais pas assez pour ce genre de demande un peu plus pointue qu'un simple "del *.*"

il faudrait que j'arrive à automatiser un effacement de fichiers plus vieux que 6 mois (par exemple) dans un repertoire plein de sous répertoire et de sous sous repertoire (etc...) à partir d'un batch lancé automatiquement à une certaine fréquence (1 fois par semaine par exemple)

donc => help

Reply

Marsh Posté le 15-06-2006 à 12:31:29

Je m'y connais pas assez

Reply

Marsh Posté le 15-06-2006 à 13:28:25

regarde l'outils robocopy de microsoft

il y a une option sur la date

Reply

Marsh Posté le 15-06-2006 à 13:39:08

un peu de google et je viens de trouver ça.
je vous donne l'info si ça peut vous interesser ça à l'air au poil (On peut même récupérer un log avec les fichiers effacés ainsi que la durée de présence sur le système (une option permet aussi de juste afficher ce rapport sans effacer les fichiers) .

http://home.mnet-online.de/horst.muc/wbat32.htm
DelAge32 1.5 Delete or move files by age Download (11Kb)

DelAge32 deletes or moves files with a mimimum age given by the number of days.

Syntax:
DelAge32 filespec days [/preview] [/created] [/includeRO] [/recurse] [/subonly] [/quiet] [/move target]

The files are specified by search pattern ("*.*" for all files), with relative or absolute path.

Example:
DelAge32 C:\some\where\*.* 100 /recurse

Deleted files are listed with age (number of days). The output can be redirected to a file.
With option /preview the action can be safely tested without actually deleting or moving files.

Reply

Marsh Posté le 19-06-2006 à 15:53:29

Avec un serveur de fichiers, on ne supprime pas, on ARCHIVE. Voici le script VBS que j'utilise avec ROBOCOPY pour archiver :

1/ Je liste avec les critères de choix : date accès, taille, type,... (pour vérifier l'espace disque à gagner),
2/ Je déplace les fichiers (en gardant l'arborescence)
3/ Je grave les fichiers,
4/ Je supprime les fichiers déplacés

Code :

'-------------------------------------------------------------
' Utilitaire : ROBOCOPY22.vbs (version 2.2)
' But Ial: Faciliter et automatiser l'utilisation de la commande DOS robocopy.exe.
' Cet utilitaire sera utilisé essentiellement pour analyser et purger les fichiers
' utilisateurs sur le serveur de fichiers.
' But IIaire : approfondir le langage de script VBS
' Installation : 1/ Ce script sur le bureau du serveur de fichier
' 2/ robocopy.exe XP010 (Ressource Kit XP) dans le répertoire %windir%
' Auteur : J.Philippe SOSSON
' Versions 1.0 Menu + options de base : copier, déplacer, lister, synchroniser,
' critères selon la taille des fichiers, date de modification
' 2.0 * Optimisation du code : Fonctions, procédures, tableaux et constantes
' * Ajout du critère selon la date d'accès
' * Correction de la fonction Mirroir : /MIR ne fonctionne pas avec l'option /XX
' 2.1 * Ajout de l'option R) pour répéter la dernière commande
' * Modification de la sortie de l'utilitaire
' 2.2 * Ajout de la gestion des messages en sortie de robocopy
' * Ajout d'un filtre sur les fichiers
'-------------------------------------------------------------
'------ Déclaration des variables et des constantes
Option Explicit '------ Forcer la déclaration des variables
Dim wsh, fso, FichierJournal
Const C_Lecture = 1, C_Ecriture = 2
Const C_FichierJournal = "c:\robocopy.txt"
Dim CmdeRobocopy
Dim ChoixMenu
Dim SaisieDossier, SaisieFichier, SaisieDate, SaisieTaille, Validation
Dim T_SelectionDossier(1)
Const C_DossierSource = 0, C_DossierDestination = 1
Dim T_SelectionDate(1, 3)
Const C_DateOption = 0, C_DateTexte = 1
Const C_DateAccesAnterieure = 0, C_DateAccesPosterieure = 1, C_DateModificationAnterieure = 2, C_DateModificationPosterieure = 3
Dim T_SelectionTaille(1, 1)
Const C_TailleOption = 0, C_TailleTexte = 1
Const C_TailleMin = 0, C_TailleMax = 1
Dim CodeRetour, Bit, T_MessageRetour(5)
'------ Déclaration des fonctions et procédures
Function SelectionDossier(TypeDossier)
Do
SaisieDossier = InputBox("Dossier" & T_SelectionDossier(TypeDossier), "ROBOCOPY" )
Loop Until fso.FolderExists(SaisieDossier)
SelectionDossier = " " & SaisieDossier
End Function
Function SelectionFichier()
SaisieFichier = InputBox("Tri sur les fichiers" & Chr(10) & "Caratères génériques acceptés, *.* par défaut", "ROBOCOPY" )
If Len(SaisieFichier) > 0 Then
SelectionFichier = " " & SaisieFichier
End If
End Function
Function ChoixDate()
'------ Filtre sur les dates d'accès OU les dates de modification
If MsgBox("Souhaitez-vous trier les fichiers sur les dates d'accès", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
ChoixDate = SelectionDate(C_DateAccesAnterieure)
ChoixDate = ChoixDate & SelectionDate(C_DateAccesPosterieure)
Else
If MsgBox("Souhaitez-vous trier les fichiers sur les dates de modification", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
ChoixDate = SelectionDate(C_DateModificationAnterieure)
ChoixDate = ChoixDate & SelectionDate(C_DateModificationPosterieure)
End If
End If
End Function
Function SelectionDate(TypeDate)
Do
Validation = 0
SaisieDate = InputBox("Fichiers dont la date" & T_SelectionDate(C_DateTexte, TypeDate) & Chr(10) _
& "Bouton [Annuler] si aucune, sinon JJ/MM/AAAA", "ROBOCOPY" )
If Len(SaisieDate) = 0 Then
Validation = vbYes
Else
if Len(SaisieDate) = 10 Then
If IsNumeric(Right(SaisieDate,4)) And IsNumeric(Mid(SaisieDate,4,2)) And IsNumeric(Left(SaisieDate,2)) Then
Validation = MsgBox("Veuillez confirmer : fichiers dont la date" _
& T_SelectionDate(C_DateTexte, TypeDate) & " à " & SaisieDate, vbYesNo + vbExclamation, "ROBOCOPY" )
If Validation = vbYes Then
SaisieDate = Right(SaisieDate,4) & Mid(SaisieDate,4,2) & Left(SaisieDate,2)
SelectionDate = T_SelectionDate(C_DateOption, TypeDate) & SaisieDate
End If
End If
End If
End If
Loop Until Validation = vbYes
End Function
Function ChoixTaille()
If MsgBox("Souhaitez-vous trier les fichiers sur la taille", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
ChoixTaille = SelectionTaille(C_TailleMin)
ChoixTaille = ChoixTaille & SelectionTaille(C_TailleMax)
End If
End Function
Function SelectionTaille(TypeTaille)
Do
Validation = 0
SaisieTaille = InputBox("Fichiers dont la taille est" & T_SelectionTaille(C_TailleTexte, TypeTaille) & Chr(10) _
& "Bouton [Annuler] si aucune, sinon X (en Go)", "ROBOCOPY" )
If Len(SaisieTaille) = 0 Then
Validation = vbYes
Else
If IsNumeric(SaisieTaille) Then
Validation = MsgBox("Veuillez confirmer : fichiers dont la taille est" _
& T_SelectionTaille(C_TailleTexte, TypeTaille) & " à " & SaisieTaille & " Go" _
, vbYesNo + vbExclamation, "ROBOCOPY" )
If Validation = vbYes Then
SelectionTaille = T_SelectionTaille(C_TailleOption, TypeTaille) & Cstr(Clng(SaisieTaille)*1024*1024)
End If
End If
End If
Loop Until Validation = vbYes
End Function
Function Journal()
Journal = " /LOG:c:\robocopy.log /NDL" 'Fichier journal et contenu
If MsgBox("Souhaitez-vous un affichage de l'exécution de la commande dans la console windows" _
, vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
Journal = Journal & " /ETA /TEE"
End If
End Function
Sub ArchiveCommande(CmdeRobocopy, TypeAcces)
Set FichierJournal = fso.OpenTextFile(C_FichierJournal, TypeAcces, True)
If TypeAcces = C_Lecture Then
CmdeRobocopy = FichierJournal.ReadLine
Else
FichierJournal.WriteLine CmdeRobocopy
End If
FichierJournal.Close
End Sub
Function MessageRetour(CodeRetour)
If CodeRetour = 0 Then
MessageRetour = T_MessageRetour(5)
Else
For Bit = 0 To 4
If (CodeRetour And (2^Bit)) = (2^Bit) Then
MessageRetour = MessageRetour & T_MessageRetour(Bit)
End If
Next
End If
End Function
Sub ExecuteCommande(CmdeRobocopy)
If MsgBox("Souhaitez-vous exécuter la commande suivante :" & Chr(10) _
& CmdeRobocopy, vbYesNo + vbExclamation, "ROBOCOPY" ) = vbYes Then
CodeRetour = wsh.Run(CmdeRobocopy, 1, True) '------ Execution avec attente de la fin de la commande
MsgBox MessageRetour(CodeRetour), vbOKOnly, "ROBOCOPY"
wsh.Run("notepad.exe c:\robocopy.log" ) '------ Ouverture du fichier journal
ArchiveCommande CmdeRobocopy, C_Ecriture
End If
End Sub
'------ Initialisation des variables
Set wsh = CreateObject("WScript.Shell" )
Set fso = CreateObject("Scripting.FileSystemObject" )
T_SelectionDossier(C_DossierSource) = " Source"
T_SelectionDossier(C_DossierDestination) = " Destination"
T_SelectionDate(C_DateOption, C_DateAccesAnterieure) = " /MINLAD:"
T_SelectionDate(C_DateOption, C_DateAccesPosterieure) = " /MAXLAD:"
T_SelectionDate(C_DateOption, C_DateModificationAnterieure) = " /MINAGE:"
T_SelectionDate(C_DateOption, C_DateModificationPosterieure) = " /MAXAGE:"
T_SelectionDate(C_DateTexte, C_DateAccesAnterieure) = " d'accès est antérieure"
T_SelectionDate(C_DateTexte, C_DateAccesPosterieure) = " d'accès est postérieure"
T_SelectionDate(C_DateTexte, C_DateModificationAnterieure) = " de modification est antérieure"
T_SelectionDate(C_DateTexte, C_DateModificationPosterieure) = " de modification est postérieure"
T_SelectionTaille(C_TailleOption, C_TailleMin) = " /MIN:"
T_SelectionTaille(C_TailleOption, C_TailleMax) = " /MAX:"
T_SelectionTaille(C_TailleTexte, C_TailleMin) = " supérieure"
T_SelectionTaille(C_TailleTexte, C_TailleMax) = " inférieure"
T_MessageRetour(0) = "Un ou plusieurs fichiers ont été copiés avec succès. "
T_MessageRetour(1) = "Certains fichiers ou dossiers sont en EXTRA (Absent de la source, mais présent dans la destination). " & _
"Visualiser le fichier journal afin d'effectuer des opérations si nécessaire (sauf en cas de listage). "
T_MessageRetour(2) = "Certains fichiers ou dossiers sont en dissonance. Visualiser le fichier journal afin d'effectuer des opérations si nécessaire. "
T_MessageRetour(3) = "Certains fichiers ou dossiers n'ont pas pu être copiés (malgré le nombre et le délai des reprises spécifiés). "
T_MessageRetour(4) = "Erreur sérieuse. Robocopy n'a copié aucun fichier. C'est une erreur d'utilisation de la commande " & _
"ou une erreur due aux privilèges d'accès insuffisants sur les dossiers sources ou destinations. "
T_MessageRetour(5) = "Aucune erreur et aucune copie : les dossiers sources et destinations sont synchronisés. "
'------ MAIN ------
Do
CmdeRobocopy = "ROBOCOPY"
'------ CHOIX DE L'ACTION ------
ChoixMenu = UCase(InputBox("Votre choix :" & Chr(10) & Chr(10) _
& "C) Copier des fichiers" & Chr(10) _
& "D) Déplacer des fichiers" & Chr(10) _
& "L) Lister des fichiers" & Chr(10) _
& "M) Synchroniser des fichiers (Mirroir)" & Chr(10) _
& "R) Répéter la dernière commande" & Chr(10) _
& Chr(10) & "Bouton [Annuler] ou [Entrée] sans valeur pour Quitter" _
,"ROBOCOPY" ))
Select Case ChoixMenu
Case "C" '------ Copier des fichiers
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
CmdeRobocopy = CmdeRobocopy & SelectionFichier()
CmdeRobocopy = CmdeRobocopy & ChoixDate()
CmdeRobocopy = CmdeRobocopy & ChoixTaille()
CmdeRobocopy = CmdeRobocopy & " /COPYALL /S /ZB" '------ Action a réaliser
CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
CmdeRobocopy = CmdeRobocopy & Journal()
ExecuteCommande CmdeRobocopy
Case "D" '------ Déplacer des fichiers
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
CmdeRobocopy = CmdeRobocopy & SelectionFichier()
CmdeRobocopy = CmdeRobocopy & ChoixDate()
CmdeRobocopy = CmdeRobocopy & ChoixTaille()
CmdeRobocopy = CmdeRobocopy & " /COPYALL /S /ZB /MOVE" '------ Action a réaliser
CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
CmdeRobocopy = CmdeRobocopy & Journal()
ExecuteCommande CmdeRobocopy
Case "L" '------ Lister des fichiers
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
CmdeRobocopy = CmdeRobocopy & " C:\" '------ Destination bidon car listage uniquement...
CmdeRobocopy = CmdeRobocopy & SelectionFichier()
CmdeRobocopy = CmdeRobocopy & ChoixDate()
CmdeRobocopy = CmdeRobocopy & ChoixTaille()
CmdeRobocopy = CmdeRobocopy & " /COPY:D /S /L /XX" '------ Action a réaliser
CmdeRobocopy = CmdeRobocopy & " /R:0 /W:0" '------ Nombre et délai pour une reprise de l'action en cas d'échec
CmdeRobocopy = CmdeRobocopy & Journal()
ExecuteCommande CmdeRobocopy
Case "M" '------ Synchroniser des fichiers (Mirroir)
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
CmdeRobocopy = CmdeRobocopy & " /COPYALL /E /ZB /MIR" '------ Action a réaliser
CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
CmdeRobocopy = CmdeRobocopy & Journal()
ExecuteCommande CmdeRobocopy
Case "R" '------ Répéter la dernière commande
If fso.FileExists(C_FichierJournal) Then
ArchiveCommande CmdeRobocopy, C_Lecture
ExecuteCommande(CmdeRobocopy)
Else
MsgBox "Commande Impossible : c:\robocopy.txt est introuvable...", vbOKOnly, "ROBOCOPY"
End If
Case "" '------ Quitter par le bouton [Annuler] ou [Entrée] sans valeur
If MsgBox("Confirmation de l'abandon de l'utilitaire", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbNo Then
ChoixMenu = "On ne quitte pas la procédure"
End If
Case Else
MsgBox "Choix de menu incorrect...", vbOKOnly, "ROBOCOPY"
End Select
Loop Until Len(ChoixMenu) = 0

Reply

Marsh Posté le 23-06-2006 à 15:06:33

heuuu, il y a un poil plus simple quand même

Une tache plannifier qui lance un .bat lancant robocopy avec :

robocopy e:\rep_a_vider\ e:\rep_de_corbeille /MOV /MINAGE:15 /LOG+:"d:\scripts\log_extract.txt"

Message cité 1 fois
Message édité par Pims le 23-06-2006 à 15:07:55

---------------
Life is like a box of chocolate you never know what you gonna get.

Reply

Marsh Posté le 23-06-2006 à 18:44:35

Pims a écrit :

heuuu, il y a un poil plus simple quand même

Une tache plannifier qui lance un .bat lancant robocopy avec :

robocopy e:\rep_a_vider\ e:\rep_de_corbeille /MOV /MINAGE:15 /LOG+:"d:\scripts\log_extract.txt"

Y'a t'il plus simple que de faire un copier/coller du script ci-joint sachant qu'il permet sans rien y connaître d'utiliser ROBOCOPY avec moultes possibiltés et options

Message cité 2 fois

Reply

Marsh Posté le 23-06-2006 à 22:18:05

Dji-Pih a écrit :

Y'a t'il plus simple que de faire un copier/coller du script ci-joint sachant qu'il permet sans rien y connaître d'utiliser ROBOCOPY avec moultes possibiltés et options

en même temps la ligne de commande de pims correspond il me semble au problème posé.

Reply

Marsh Posté le 23-06-2006 à 22:18:05

Reply

Marsh Posté le 27-06-2006 à 12:29:00

Dji-Pih a écrit :

Y'a t'il plus simple que de faire un copier/coller du script ci-joint sachant qu'il permet sans rien y connaître d'utiliser ROBOCOPY avec moultes possibiltés et options

Non, je ne pense pas qu'il y ai plus simple...

Mais il y a plus intelligent, faire un: robocopy /?

Message cité 1 fois

---------------
Life is like a box of chocolate you never know what you gonna get.

Reply

Marsh Posté le 27-06-2006 à 17:46:47

Pims a écrit :

Non, je ne pense pas qu'il y ai plus simple...

Mais il y a plus intelligent, faire un: robocopy /?

Pour ceux que ça interresse de devenir intelligent... :ange:

Code :

-------------------------------------------------------------------------------
ROBOCOPY :: Robust File Copy for Windows :: Version XP010
-------------------------------------------------------------------------------
Started : Tue Jun 27 17:36:54 2006
Usage :: ROBOCOPY source destination [file [file]...] [options]
source :: Source Directory (drive:\path or \\server\share\path).
destination :: Destination Dir (drive:\path or \\server\share\path).
file :: File(s) to copy (names/wildcards: default is "*.*" ).
::
:: Copy options :
::
/S :: copy Subdirectories, but not empty ones.
/E :: copy subdirectories, including Empty ones.
/LEV:n :: only copy the top n LEVels of the source directory tree.
/Z :: copy files in restartable mode.
/B :: copy files in Backup mode.
/ZB :: use restartable mode; if access denied use Backup mode.
/COPY:copyflag[s] :: what to COPY (default is /COPY:DAT).
(copyflags : D=Data, A=Attributes, T=Timestamps).
(S=Security=NTFS ACLs, O=Owner info, U=aUditing info).
/SEC :: copy files with SECurity (equivalent to /COPY:DATS).
/COPYALL :: COPY ALL file info (equivalent to /COPY:DATSOU).
/NOCOPY :: COPY NO file info (useful with /PURGE).
/PURGE :: delete dest files/dirs that no longer exist in source.
/MIR :: MIRror a directory tree (equivalent to /E plus /PURGE).
/MOV :: MOVe files (delete from source after copying).
/MOVE :: MOVE files AND dirs (delete from source after copying).
/A+:[RASHNT] :: add the given Attributes to copied files.
/A-:[RASHNT] :: remove the given Attributes from copied files.
/CREATE :: CREATE directory tree and zero-length files only.
/FAT :: create destination files using 8.3 FAT file names only.
/FFT :: assume FAT File Times (2-second granularity).
/256 :: turn off very long path (> 256 characters) support.
/MON:n :: MONitor source; run again when more than n changes seen.
/MOT:m :: MOnitor source; run again in m minutes Time, if changed.
/RH:hhmm-hhmm :: Run Hours - times when new copies may be started.
/PF :: check run hours on a Per File (not per pass) basis.
/IPG:n :: Inter-Packet Gap (ms), to free bandwidth on slow lines.
::
:: File Selection Options :
::
/A :: copy only files with the Archive attribute set.
/M :: copy only files with the Archive attribute and reset it.
/IA:[RASHCNETO] :: Include only files with any of the given Attributes set.
/XA:[RASHCNETO] :: eXclude files with any of the given Attributes set.
/XF file [file]... :: eXclude Files matching given names/paths/wildcards.
/XD dirs [dirs]... :: eXclude Directories matching given names/paths.
/XC :: eXclude Changed files.
/XN :: eXclude Newer files.
/XO :: eXclude Older files.
/XX :: eXclude eXtra files and directories.
/XL :: eXclude Lonely files and directories.
/IS :: Include Same files.
/IT :: Include Tweaked files.
/MAX:n :: MAXimum file size - exclude files bigger than n bytes.
/MIN:n :: MINimum file size - exclude files smaller than n bytes.
/MAXAGE:n :: MAXimum file AGE - exclude files older than n days/date.
/MINAGE:n :: MINimum file AGE - exclude files newer than n days/date.
/MAXLAD:n :: MAXimum Last Access Date - exclude files unused since n.
/MINLAD:n :: MINimum Last Access Date - exclude files used since n.
(If n < 1900 then n = n days, else n = YYYYMMDD date).
/XJ :: eXclude Junction points. (normally included by default).
::
:: Retry Options :
::
/R:n :: number of Retries on failed copies: default 1 million.
/W:n :: Wait time between retries: default is 30 seconds.
/REG :: Save /R:n and /W:n in the Registry as default settings.
/TBD :: wait for sharenames To Be Defined (retry error 67).
::
:: Logging Options :
::
/L :: List only - don't copy, timestamp or delete any files.
/X :: report all eXtra files, not just those selected.
/V :: produce Verbose output, showing skipped files.
/TS :: include source file Time Stamps in the output.
/FP :: include Full Pathname of files in the output.
/NS :: No Size - don't log file sizes.
/NC :: No Class - don't log file classes.
/NFL :: No File List - don't log file names.
/NDL :: No Directory List - don't log directory names.
/NP :: No Progress - don't display % copied.
/ETA :: show Estimated Time of Arrival of copied files.
/LOG:file :: output status to LOG file (overwrite existing log).
/LOG+:file :: output status to LOG file (append to existing log).
/TEE :: output to console window, as well as the log file.
/NJH :: No Job Header.
/NJS :: No Job Summary.
::
:: Job Options :
::
/JOB:jobname :: take parameters from the named JOB file.
/SAVE:jobname :: SAVE parameters to the named job file
/QUIT :: QUIT after processing command line (to view parameters).
/NOSD :: NO Source Directory is specified.
/NODD :: NO Destination Directory is specified.
/IF :: Include the following Files.

Evidemment, si vous voulez gérer les codes d'erreurs de sortie de la commande robocopy, ou ce qu'est un type de fichier "Extra", ou bien d'autres informations utiles, inutile de les chercher avec robocopy /? car la il faut être super-intelligent... :sol:
:hello:

Reply

automatiser un effacement de fichiers ?

Sujets relatifs:

Leave a Replay