Evenement inconnu sur un bouton ?

Evenement inconnu sur un bouton ? - Flash/ActionScript - Programmation

Marsh Posté le 27-10-2007 à 21:54:14    

Bonjour,
 
Je cherche a recréer une classe bouton en AS3 car je la voudrais plus ou moins animée...
 
Seulement si j'arrive à intercepter les événements pour le survole et le clique de la souris, il y en a un spécial qui m’échappe complètement :
 
Par exemple avec un simple bouton (voir code ci dessous) en plaçant la curseur sur le bouton et en enfonçant la souris (et en restant enfoncer) on peut trimballer le curseur sur tout l’écran et le bouton a toujours sa couleur de recouvrement.
 
Jusque là j'arrive à reproduire... sauf ceci :
 
La souris toujours enfoncé, je place le curseur en dehors de la fenêtre de Flash et là je relâche la souris. Aussitôt le bouton reprend sa couleur de base. Je n’arrive pas à émuler cet événement !
 
Tous les essais de Bouton extension de Sprite font que je n‘ai plus aucun événement émanant de mon bouton dès que je sors de sa zone même avec la souris enfoncée.
 
Il y a sûrement un truc tout con, genre une propriété à initialiser. En tout cas je ne pense pas qu’il faille de bidouille car la classe SimpleButton fonctionne très bien même en bougeant le curseur en dehors de la fenêtre du logiciel Flash.
 
Connaissez vous la solution ?
 
Merki beauku !
 

Code :
  1. package
  2. {
  3.  import flash.display.*;
  4.  public class Test extends Sprite
  5.  {
  6.   public function Test()
  7.   {
  8.    var myButton:SimpleButton = new SimpleButton();
  10.    myButton.upState = createSpriteRect(32,32,64,32, 0xFF0000);
  11.    myButton.overState = createSpriteRect(32,32,64,32, 0x00FF00);
  12.    myButton.downState = createSpriteRect(32,32,64,32, 0x0000FF);
  13.    myButton.hitTestState = createSpriteRect(32,32,64,32, 0xFF00FF);
  15.    this.addChild(myButton);
  16.   }
  18.   private function createSpriteRect(x:int, y:int, w:int, h:int, color:int):Sprite
  19.   {
  20.    var sprite:Sprite = new Sprite();
  21.    sprite.graphics.lineStyle(2, 0x202020);
  22.    sprite.graphics.beginFill(color);
  23.    sprite.graphics.drawRect(x, y, w, h);
  24.    return sprite;
  25.   }
  26.  }
  27. }

Reply

Marsh Posté le 27-10-2007 à 21:54:14   

Reply

Marsh Posté le 29-10-2007 à 20:52:49    

Bon bah j'ai réussi tout seul :D  
 
J'ai réussi à récupérer l’événement du retour-de-click qui fait défaut lorqu'il est dévié.
 
Comme ça ma classe Bouton fonctionne exactement comme les vrais-boutons  :na:
 
Si cela intéresse quelqu’un...
 
J'ai constaté que le retour-de-click-dévié n'est intercepté que par la classe Stage  
 
Pourquoi ? ça j'en sais rien !
 
Donc il suffit de faire en sorte que l'évènement MOUSE_UP de ma classe soit pris en compte par le stage.
 
Voici le code-source pour comprendre (pour l'exemple mon bouton est plus que rudimentaire) :
 

Code :
  1. package
  2. {
  3. import flash.display.*;
  4. import flash.events.*;
  6. public class MySimpleButton extends Sprite
  7. {
  8.  private var _focused:Boolean = false;
  9.  private var _pushed:Boolean = false;
  11.  public function MySimpleButton()
  12.  {
  13.   _draw();
  14.   addEventListener(Event.ADDED, initEvents);
  15.  }
  17.  private function initEvents(e:Event):void
  18.  {
  19.   if(stage!=null)
  20.   {
  21.    addEventListener(MouseEvent.MOUSE_OVER, _mouseOver);
  22.    addEventListener(MouseEvent.MOUSE_OUT, _mouseOut);
  24.    addEventListener(MouseEvent.MOUSE_DOWN, _mouseDown);
  25.    stage.addEventListener(MouseEvent.MOUSE_UP, _mouseUp);
  26.   }
  27.   else
  28.   {
  29.    var ancienter:DisplayObjectContainer = parent;
  30.    while(ancienter.parent!=null) ancienter = ancienter.parent;
  31.    ancienter.addEventListener(Event.ADDED, initEvents);
  32.   }
  33.  }
  35.  protected function _draw():void
  36.  {
  37.   var f:int = _focused? 0xFF0000 : 0;
  38.   var p:int = _pushed? 0x00FF00 : 0;
  40.   graphics.clear();
  41.   graphics.beginFill(f+p);
  42.   graphics.drawRect(0,0,128,32);
  43.   graphics.endFill();
  44.  }
  46.     private function _mouseOut(e:MouseEvent):void
  47.     {
  48.      _focused = false;
  49.      _draw();
  50.     }
  51.    
  52.     private function _mouseOver(e:MouseEvent):void
  53.     {
  54.      _focused = true;
  55.      _draw();
  56.     }
  58.     private function _mouseDown(e:MouseEvent):void
  59.     {
  60.      _pushed = true;
  61.      _draw();
  62.     }
  63.    
  64.     private function _mouseUp(e:MouseEvent):void
  65.     {
  66.      if(_pushed==true)
  67.      {
  68.          _pushed = false;
  69.       _draw();
  70.      }
  71.     }    
  72. }
  73. }


 
 
Note : pour l'attachement/détachement au stage... il y a encore des améliorations à faire.
 
 
 :hello:

Reply

Marsh Posté le 29-10-2007 à 22:52:04    

euh, c'est pas nécessaire de poster ce genre de code, t'as un peu inventé l'eau tiède là :-/
 

Message cité 1 fois
Reply

Marsh Posté le 31-10-2007 à 01:41:01    

antika a écrit :

euh, c'est pas nécessaire de poster ce genre de code, t'as un peu inventé l'eau tiède là :-/


 
Il me semblait être sur un forum d’entraide !
 
Tout le monde n’a pas forcement Bac + 8 en Flash comme toi  
 
Je pars du principe qu’une personne doit s’intéresser au sujet si elle tombe ici.
 
Si elle cherche une solution,  il y aura au moins la mienne accessible au novice.
 
Autrement si le sujet et trop bateau pour elle… pourquoi viendrait-elle le dire !?
 
 
En tout cas pour moi, il y avait quelque chose à montrer ici.
 
Car sur d’autres langages l’événement type Mouse_Up est correctement intercepté.  
 
P’tit Bug Flash ou pas encore assez approfondi Flash !
 
 

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed