[Resolu] Interruption mode reel depuis mode protegé avec DPMI

Interruption mode reel depuis mode protegé avec DPMI [Resolu] - ASM - Programmation

Marsh Posté le 19-11-2015 à 16:04:43    

Bonjour,
 
J'ai un programme en Borland Pascal 7 qui doit etre compilé en mode protégé. Dans ce programme, j'ai un appel a un interruption du mode réel. Donc j'ai besoin d'utiliser l'assembleur et les fonctions du DPMI.
Or mes connaissances en assembleur, DPMI et mémoire DOS sont proches du 0  :D
 
J'ai trouvé dans les spécifications du DMPI, le "Simulate Real Mode Interrupt" 0300H. http://www.ctyme.com/intr/rb-5831.htm
 
J'ai même trouvé des exemples :

Code :
  1. function  Intr386(const int_number:byte; const stack_words:word;
  2.                   var regs:DPMIRegisters) : word; assembler;
  3. (* Make Real Mode interrupt while in Protected Mode.         *)
  4. asm
  5.    xor bx,bx                                       { clear bx }
  6.    mov bl,int_number                  { load interrupt number }
  7.    mov cx,stack_words                       { get stack words }
  8.    les di,regs               { load effective address of regs }
  9.    mov ax,0300h                        { function number 300h }
  10.    int 31h                                   { call interrupt }
  11.    jc @pexit              { if error jump to end of procedure }
  12.    xor ax,ax                           { clear ax; successful }
  13. @pexit:                                    { end of procedure }
  14. end;


 

Code :
  1. type DPMIRegisters = record    { registers for DPMI int calls }
  2.       case byte of
  3.            1 : (EDI,ESI,EBP,EReserved,
  4.                 EBX,EDX,ECX,EAX:longint;
  5.                 Flags,ES,DS,FS,GS,
  6.                 IP,CS,SP,SS:word);
  7.            2 : (DI,XDI,SI,XSI,BP,XBP,Reserved,
  8.                 XReserved,BX,XBX,DX,XDX,CX,XCX,
  9.                 AX,XAX:word);
  10.            3 : (DIL,DIH,XDIL,XDIH,
  11.                 SIL,SIH,XSIL,XSIH,
  12.                 BPL,BPH,XBPL,XBPH,
  13.                 ReservedL,ReservedH,
  14.                 XReservedL,XReservedH,
  15.                 BL,BH,XBL,XBH,
  16.                 DL,DH,XDL,XDH,
  17.                 CL,CH,XCL,XCH,
  18.                 AL,AH,XAL,XAH,
  19.                 FlagsL,FlagsH,
  20.                 ESL,ESH,DSL,DSH,FSL,FSH,
  21.                 GSL,GSH,IPL,IPH,CSL,CSH,
  22.                 SPL,SPH,SSL,SSH:byte);
  23.         end;


 
Mais voilà, le hic c'est que je dois faire passer lors de mon appel à mon interruption $65, la structure suivante, qui de plus contient des buffers !!

Code :
  1. Type
  2. urbtype = Record
  3. transaction_token: byte (* control (2Dh), in (69h), out (E1h) as hex code *);
  4. chain_end_flag   : byte {another urb follow this urb in memory? zero=no,one=yes};
  5. dev_add          : byte;
  6. end_point        : byte;
  7. error_code       : byte;
  8. status           : byte (* returned by dosuhci *);
  9. transaction_flags: word (* reserved *);
  10. buffer_off       : word (* for in/out *);
  11. buffer_seg       : word (* for in/out *);
  12. buffer_length    : word (* for in/out *);
  13. actual_length    : word (* for in/out *);
  14. setup_buffer_off : word (* for control *);
  15. setup_buffer_seg : word (* for control *);
  16. start_frame      : word (* reserved *);
  17. nr_of_packets    : word (* iso *);
  18. int_interval     : byte (* reserved *);
  19. error_count      : byte (* reserved *);
  20. timeout          : word (* reserved *);
  21. next_urb_off     : word (* reserved *);
  22. next_urb_seg     : word (* reserved *);
  23. end (* 32 byte long *);


 

Code :
  1. Procedure do_out;  (* To PIC *)
  3. Var
  4. Reg: Registers;
  5. Begin
  6. (* set up out request *)
  7. urb.transaction_token := $E1;(* $E1= Sortie*)
  8. urb.chain_end_flag := 0;
  9. urb.dev_add := the_dev_add; 
  10. urb.end_point := out_endpoint;
  11. urb.error_code := 0;
  12. urb.status := 0;
  13. urb.transaction_flags := 0;
  14. urb.buffer_off := ofs(buffer_o);
  15. urb.buffer_seg := seg(buffer_o);
  16. urb.buffer_length := packetlen;
  17. urb.actual_length := 64;
  18. urb.setup_buffer_off := 0;
  19. urb.setup_buffer_seg := 0;
  20. urb.start_frame := 0;
  21. urb.nr_of_packets := 0;
  22. urb.int_interval := 0;
  23. urb.error_count := 0;
  24. urb.timeout := 0;
  25. urb.next_urb_off := 0;
  26. urb.next_urb_seg := 0;
  28. (* now call DosUHCI *)
  29. Reg.DS := seg(urb);
  30. Reg.DX := ofs(urb);
  31. Intr($65, Reg); (*NE FONCTIONNE PAS EN MODE PROTEGE*)
  33. Inc(ReqNr);
  34. End (* do_out *);


 
Bref ça fait 2 semaines que je suis dessus et que je mouline. N'hesitez pas a me poser des questions. J'ai toujours des difficultés pour arriver à etre clair.
 
Merci


Message édité par rocky77 le 25-11-2015 à 00:15:50
Reply

Marsh Posté le 19-11-2015 à 16:04:43   

Reply

Marsh Posté le 19-11-2015 à 17:07:06    

Alors je regarderais ce que j'ai dans mes archives.
Comme je disais en MP, ça fait 15 ans que j'ai pas fait ça :D

Reply

Marsh Posté le 19-11-2015 à 17:17:22    

Une doc un peu plus claire:
http://www.delorie.com/djgpp/doc/dpmi/api/310300.html


Message édité par bjone le 20-11-2015 à 14:59:29
Reply

Marsh Posté le 20-11-2015 à 14:18:15    

J'avais deja reperé cette doc.

 

Je vais tenter par faire un truc simple.

 
Code :
  1. asm
  2.    mov ah, 2Ch   //Fonction 2Ch Gettime
  3.    int 21h           //Dos Int.
  4.    mov hour, CH
  5.    mov minut, CL
  6. end;
  7. writeln('Heure',hour,':',minut);
 

Ce code fonctionne car dmpi converti automatiquement l'interruption en mode reel.(automatic mirroring of interrupts into real mode by DMPI). Donc je vais essayer de refaire ce code comme si DMPI ne prenait pas en charge cette conversion, et du coup essayer d'utiliser le 300h (simulation interruption mode reel)...Toute aide est le bienvenue  :)


Message édité par rocky77 le 20-11-2015 à 14:19:01
Reply

Marsh Posté le 20-11-2015 à 15:01:23    

Désolé, j'ai pas pris le temps de regarder dans mes archives.
 
Par contre du cas tu en es où ?
Tu fait ton appel dpmi et ça crashe ?

Reply

Marsh Posté le 20-11-2015 à 15:07:43    

J'en suis a essayer de comprendre comment faire pour allouer ma structure et mes buffer dans le bloc memoire dos.
Donc dans un premier temps, j'essaie avec l'exemple de la fonction gettime ou il n'a que la fonction 2Ch à passer.
Puis j’essaierais avec la fonction 09h (afficher du texte) qui necessite en plus de transferrer du texte.
 
Et si ca marche je continue avec ma structure et mes buffers.
 

Code :
  1. Program heure;
  3. USES CRT,dos, winapi;
  5. type
  6. DPMIRegisters = Record  {Registers for DPMI int callst}
  7.     DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
  8.     DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
  9.     DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
  10.     DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
  11. end;
  13. var
  14.   hour, minute : shortint;
  15.   dcs : DPMIRegisters;
  16.   transfer_Buf_Seg: word;
  17.   transfer_Buf : word;
  19. function Intr386(const int_number:byte; const stack_words:word;
  20.                        var regs:DPMIRegisters): word; assembler;
  21. asm
  22.    xor bx, bx
  23.    mov bl, int_number
  24.    mov cx, stack_words
  25.   ; mov dx, ds
  26.   ; mov es, dx
  27.    les di,regs
  28.    mov ax, 0300h
  29.    int 31h
  30. end;
  32. BEGIN
  33. asm
  34.    mov ax, 0100h
  35.    mov bx, 8
  36.    int 31h
  37.    mov [transfer_Buf], dx
  38.    mov [transfer_Buf_Seg], ax
  40.    mov word[dcs.DPMI_EAX], 2Ch
  41.    mov word[dcs.DPMI_EDX], 0
  42.    mov ax, [transfer_Buf_Seg]
  43.    mov word[dcs.DPMI_DS], ax
  44.   end;
  45.    writeln('debut appel');
  46.    intr386($21,0,dcs);
  47.   writeln('hour ',hour,':',minute);
  48. END.


 
Je me retrouve avec une erreur d'allocation memoire :(


Message édité par rocky77 le 20-11-2015 à 16:00:14
Reply

Marsh Posté le 20-11-2015 à 16:44:18    

Si tu est bien en adressage flat 32bits, ça devrait être:
 
les edi, regs
 
mais lds sous-entends que "var regs:DPMIRegisters" devrait faire que "regs" résoudra vers une pointeur far de "dcs" en mode protégé (sélecteur 16bits:offset 32bits).
 
Si "regs" résous vers l'offset même de la structure "dcs" (sous-entendu par rapport à ds), alors il faut utiliser "lea edi,[dcs]".
(dans cas copier ds dans es, comme tu avais mis en commentaire)
 
 

Reply

Marsh Posté le 20-11-2015 à 17:59:08    

Première étape, la plus simple, enfin bonne. J'ai tout revu, je m’étais planté dans le placement de mon 2C.  
J'arrive a récupérer l'heure système a partir d'une simulation d'interruption (300h)
 

Code :
  1. Program tmem;
  3. USES CRT,dos, winapi;
  5. type
  6. DPMIRegisters = Record  {Registers for DPMI int callst}
  7.     DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
  8.     DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
  9.     DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
  10.     DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
  11. end;
  13. var
  14.   hour, minute : shortint;
  15.   dcs : DPMIRegisters;
  16.   transfer_Buf_Seg: word;
  17.   transfer_Buf : word;
  18.   selector, segment : word;
  19.   selseg :longint;
  21. function Intr386(const int_number:byte; const stack_words:word;
  22.                        var regs:DPMIRegisters): word; assembler;
  23. asm
  24.    push es
  25.    push di
  26.    xor bx, bx
  27.    mov bl, int_number
  28.    mov cx, stack_words
  29.    les di,regs
  30.    mov ax, 0300h
  31.    int 31h
  32.    pop di
  33.    pop es
  34. end;
  36. BEGIN
  37.    dcs.DPMI_EAX := $00002C00;  {fonction 2C de int $21}
  38.    dcs.DPMI_EDI := 0;
  39.    writeln('debut appel');
  40.    intr386($21,0,dcs);
  41.    hour:=word(dcs.DPMI_ECX SHR 8);
  42.    minute:=word(dcs.DPMI_ECX AND $00FF);
  43.    writeln('dcs = ',word(dcs.DPMI_ECX));
  44.    writeln('hour ',hour,':',minute);
  45.   repeat until keypressed;
  46. END.


 
 Prochaine étape. Essayer d'envoyer la structure suivante sur l'interruption $65. Ca attendra lundi :)
 

Code :
  1. urb.transaction_token := $E1;(* $E1= Sortie*)
  2. urb.chain_end_flag := 0;
  3. urb.dev_add := the_dev_add;  (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
  4. urb.end_point := out_endpoint;    (* =1 *)
  5. urb.error_code := 0;
  6. urb.status := 0;
  7. urb.transaction_flags := 0;
  8. urb.buffer_off := ofs(buffer_o);
  9. urb.buffer_seg := seg(buffer_o);
  10. urb.buffer_length := packetlen;
  11. urb.actual_length := 64;
  12. urb.setup_buffer_off := 0;
  13. urb.setup_buffer_seg := 0;
  14. urb.start_frame := 0;
  15. urb.nr_of_packets := 0;
  16. urb.int_interval := 0;
  17. urb.error_count := 0;
  18. urb.timeout := 0;
  19. urb.next_urb_off := 0;
  20. urb.next_urb_seg := 0;


Reply

Marsh Posté le 23-11-2015 à 14:43:27    

J'ai vu sous Borland pascal une fonction qui me semble intéressante  
GlobalDosAlloc qui me permet d'allouer un zone mémoire sous les 640k
 

Code :
  1. var
  2. selseg : longint;
  3. segment, selector :word
  4. .....
  6. selseg   := globaldosalloc (64) {64 bytes taille de l'espace memoire sous less 640k.}
  7. selector := word(selseg and $FFFF); {conversion en word - le poids faible determine le selecteur pour utilisation mode protegé}
  8. segment := word(selseg and SHR 16); {conversion en word - le poids fort determine le segment pour utilisation mode reel}

 
 
 
Mais là je ne sais pas trop comment m''y prendre. J'ai ma structure urb qui est actuellement en mémoire protegé. Il faudrait que je puisse la copier en mémoire réel ainsi que son contenu. Mais comment ?


Message édité par rocky77 le 23-11-2015 à 14:44:01
Reply

Marsh Posté le 23-11-2015 à 15:53:58    

GlobalDosAlloc ça permet effectivement de communiquer avec des services nécessitant des grosses structures en mémoire conventionnelle.
 
Après il y a un truc que je comprends pas : vu winapi et des registres -que- 16bits dans ton source, tu fais quoi avec BC7 ? un projet win16 ?
 
Ou alors ton projet est bien setupé pour du mode protégé (opérandes implicitement 32bits pour les même opcodes 16bits du mode réel), et tu utilises sciemment ce trick pour contourner les limites de BP7 ?
 
Normalement on faisait plutôt du DPMI pour un jeu/une démo sous à Dos à l'époque.
 
Si c'est pour attaquer un PIC en USB, normalement en Win32/64, tu as WinUSB & co...


Message édité par bjone le 23-11-2015 à 16:03:59
Reply

Marsh Posté le 23-11-2015 à 15:53:58   

Reply

Marsh Posté le 23-11-2015 à 16:10:05    

Oui c'est un projet qui doit tourner uniquement sous dos et qui doit obligatoirement être compilé en protected mode. Borland Pascal 7 sait gerer le DMPI.
 
Mon but est de pouvoir à partir de mon programme faire appel a un programme résident (un driver USB - DOSUSB.COM) via l'interruption 65 en envoyant la structure URB qui contient le segment et l'offset d'un buffer.
 
Tu me dis si je ne suis pas clair :pt1cable:  
 
Je viens de trouver ça aussi, je vais voir si je peux m'en servir
ProtectedAddr := Ptr(L and $FFFF, 0);  
Move( FontData, ProtectedAddr^, Size);
 
Edit : Ah qu'est ce que j'aurais voulu utliser WinUSB, ca m'aurait bien facilité la tache. Malheuresement, on m'impose BP7 (mon boss), Compilation en mode protected et bien sur que ca tourne sous dos, le vrai MS DOS

Message cité 1 fois
Message édité par rocky77 le 23-11-2015 à 16:13:22
Reply

Marsh Posté le 23-11-2015 à 17:52:53    

Je pense que je progresse, mais aussi que je me melange les pinceaux. J'ai toujours du mal avec les notions de segments, selector, offset ....malgré la lecture de documentation
 

Code :
  1. Uses DOS, CRT, WINAPI;
  3. Const
  4. the_dev_add = 1;    (*Adresse peripherique usb*)
  5. in_endpoint = 1;
  6. out_endpoint = 1;    (* 2 avant *)
  7. (* myFN = 'dosuhci.txt';*)
  8. ATTENTE : INTEGER = 800  ;
  10. type
  11. DPMIRegisters = Record  {Registers for DPMI int callst}
  12.     DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
  13.     DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
  14.     DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
  15.     DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
  16. end;
  18. (* define structure of URB *)
  19. Type
  20. urbtype = Record
  21. transaction_token: byte (* control (2Dh), in (69h), out (E1h) as hex code *);
  22. chain_end_flag   : byte {another urb follow this urb in memory? zero=no,one=yes};
  23. dev_add          : byte;
  24. end_point        : byte;
  25. error_code       : byte;
  26. status           : byte (* returned by dosuhci *);
  27. transaction_flags: word (* reserved *);
  28. buffer_off       : word (* for in/out *);
  29. buffer_seg       : word (* for in/out *);
  30. buffer_length    : word (* for in/out *);
  31. actual_length    : word (* for in/out *);
  32. setup_buffer_off : word (* for control *);
  33. setup_buffer_seg : word (* for control *);
  34. start_frame      : word (* reserved *);
  35. nr_of_packets    : word (* iso *);
  36. int_interval     : byte (* reserved *);
  37. error_count      : byte (* reserved *);
  38. timeout          : word (* reserved *);
  39. next_urb_off     : word (* reserved *);
  40. next_urb_seg     : word (* reserved *);
  41. end (* 32 byte long *);
  43. type
  44. buffer = Array[0..255] Of Byte;
  45. p_buffer = ^buffer;
  47. Var
  48. urb: urbtype;
  49. buffer_o: Array[0..(*1024-1*)255] Of Byte;
  50. buffer_i: Array[0..(*1024-1*)255] Of Byte;
  51. packetlen: Word;
  52. bStr: String;
  53. f: File;
  54. ReqNr: Word;
  55. tab_out: Array[0..16] Of Byte;   {To PIC}
  56. tab_in: Array[0..32] Of Byte;   {From PIC}
  57. i,j,choix,val,quit_proc,quit_ok: integer;
  58. SNOOPY, TEST_SNOOPY : BOOLEAN ;
  59. selseg, selseg_buff :longint;
  60. selector, selector_buff, segment, segment_buff : word;
  61. P_PM : p_buffer;
  62. P_PM_buff : p_buffer;
  64. function Intr386(const int_number:byte; const stack_words:word;
  65.                        var regs:DPMIRegisters): word; assembler;
  66. asm
  67.    push es
  68.    push di
  69.    xor bx, bx
  70.    mov bl, int_number
  71.    mov cx, stack_words
  72.    les di,regs
  73.    mov ax, 0300h
  74.    int 31h
  75.    pop di
  76.    pop es
  77. end;
  80. {//////////////////////////// DO_OUT //////////////////////////////////}
  81. Procedure do_out;  { To PIC }
  82. Var
  83.   DCS : DPMIRegisters;
  84. Begin
  85. selseg := globaldosalloc(40 );
  86. selector := word(selseg and $FFFF);
  87. segment := word(selseg SHR 16);
  88. P_PM:=ptr(selector,0);  {pointeur pour remplir ma structure dans la memoire <640k}
  90. writeln('1 ');
  91. selseg_buff := globaldosalloc(257);
  92. selector_buff := word(selseg_buff and $FFFF);
  93. segment_buff := word(selseg_buff SHR 16);
  94. P_PM_buff:=ptr(selector_buff,0);  {pointeur pour remplir mon buffer dans la memoire <640k}
  95. writeln('2 - size de buffer_o = ',sizeof(buffer_o));
  97. move(buffer_o,P_PM_Buff^,sizeof(buffer_o)); {copie des données du buffer dans la memoire <640k}
  99. writeln('3 ',P_PM_Buff^[0],' ',P_PM_Buff^[1],' ',P_PM_Buff^[2]);
  100. (* set up out request *)
  101. urb.transaction_token := $E1;(* $E1= Sortie*)
  102. urb.chain_end_flag := 0;
  103. urb.dev_add := the_dev_add;  (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
  104. urb.end_point := out_endpoint;    (* =1 *)
  105. urb.error_code := 0;
  106. urb.status := 0;
  107. urb.transaction_flags := 0;
  108. urb.buffer_off := 0;(*ofs(P_PM_Buff^);*) {quoi mettre ??? ofs(P_PM_Buff^) ? 0? autre?}
  109. urb.buffer_seg := selector_buff;(*(seg(P_PM_Buff^);*) {quoi mettre ??? seg(P_PM_Buff^) ? autre ?
  110. urb.buffer_length := packetlen;
  111. urb.actual_length := 64;
  112. urb.setup_buffer_off := 0;
  113. urb.setup_buffer_seg := 0;
  114. urb.start_frame := 0;
  115. urb.nr_of_packets := 0;
  116. urb.int_interval := 0;
  117. urb.error_count := 0;
  118. urb.timeout := 0;
  119. urb.next_urb_off := 0;
  120. urb.next_urb_seg := 0;
  122. (* now call DosUHCI *)
  123. fillchar(dcs, sizeof(dcs), 0);
  124. move(urb,P_PM^,sizeof(urb));  {copie des données de la struct. URB dans la memoire <640k}
  125. writeln('4');
  126. DCS.DPMI_ES := segment;{Est ce vraiment ca qu'il faut mettre}
  127. DCS.DPMI_DS := seg(P_PM^); {Est ce vraiment ca qu'il faut mettre}
  128. DCS.DPMI_EDX :=ofs(P_PM^);{Est ce vraiment ca qu'il faut mettre}
  129. writeln('5');
  130. intr386($65, 0, dcs);
  131. GlobalDosFree(selector);
  132. GlobalDosFree(selector_buff);
  133. (* Reg.DS := seg(urb); {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
  134. Reg.DX := ofs(urb); {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
  135. Intr($65,Reg);*) {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
  136. Inc(ReqNr);
  137. End (* do_out *);
  139. (*//////////////////////////// MAIN ////////////////////////////////////*)
  140. Begin
  141.   ReqNr:=0;
  142.   for i:=0 to 16 do tab_out[i]:=0;
  143.   tab_out[2] := 64;
  144.   packetlen:=17;
  145.   for i:=0 to 16 do buffer_o[i]:=tab_out[i];
  146.   do_out;
  147.   repeat until keypressed;
  148. end. (* AXUSB.PAS *)


Message édité par rocky77 le 24-11-2015 à 10:55:53
Reply

Marsh Posté le 23-11-2015 à 18:22:21    

[:drapal]

Reply

Marsh Posté le 25-11-2015 à 00:11:33    

Probleme résolu !
 
Merci à tous, je posterais la soluce demain, tranquillement.

Reply

Marsh Posté le 25-11-2015 à 10:01:47    

rocky77 a écrit :


Edit : Ah qu'est ce que j'aurais voulu utliser WinUSB, ca m'aurait bien facilité la tache. Malheuresement, on m'impose BP7 (mon boss), Compilation en mode protected et bien sur que ca tourne sous dos, le vrai MS DOS


 
Dans un contexte professionnel, si c'est pour maintenir du vieux software utilisé en production je veux bien (typique de l'info indus), mais autrement ce serait plus sain de rebooter l'appli avec un outil moderne et pérenne.

Reply

Marsh Posté le 25-11-2015 à 10:38:42    

J'ai deja tenté de dire à mon boss qu'il serait temps de mettre à niveau le programme (qui doit bien avoir 50000 lignes de code). Mais il aime bien les vieux trucs et surtout veut pas se lancer dans cette mise à niveau.
Du coup, on se fait ch.., enfin je me fais ch... pour la maintenance de son programme indigeste :pt1cable: :fou:

Reply

Marsh Posté le 25-11-2015 à 10:49:44    

Le prob c'est que pour une réécriture d'un soft, il faut de la force de frappe.
 
Maintenant le premier truc à voir c'est le ratio code "fonctionnel" (ce qui est réellement utilie, ce qui traite vraiment de la donnée)/ code "inutile" (ce qui est imposé par les frameworks : ie par exemple les MFC sont responsables d'un gros tas de merde dans beaucoup de projets qui datent de la fin des années 90).
 
En réutilisant un framework moderne, tu élagues les lignes de caca en dégageant un gros volume de code useless. (ie Winforms vs MFC, etc...)
 
Bon là avec BP7, si vous voulez rester en Pascal pour pas perdre vos habitues, rebooter l'appli en Delphi (embarcadero) peut être une étape rentable : ça permettrait d'élaguer beaucoup de mochetés.
 

Spoiler :

Si vous êtes dans une PME, vous êtes typiquement verrouillés dans le soft écrit il y a 10 ans, que vous avez pas le budget pour le refacto, et que vous ferez une murale lorsqu'un concurrent refera un soft équivalent mais moderne, qui lui aussi repartira dans le cycle de 10~15ans avant de faire sprotch à son tour :D


Message édité par bjone le 25-11-2015 à 10:58:09
Reply

Marsh Posté le 25-11-2015 à 11:17:05    

Pour la forme, voici ma solution
 

Code :
  1. function Intr386(const int_number:byte; const stack_words:word;
  2.                        var regs:DPMIRegisters): word; assembler;
  3. asm
  4.    push es
  5.    push di
  6.    xor bx, bx
  7.    mov bl, int_number
  8.    mov cx, stack_words
  9.    les di,regs
  10.    mov ax, 0300h
  11.    int 31h
  12.    pop di
  13.    pop es
  14. end;
  17. (*//////////////////////////// DO_OUT //////////////////////////////////*)
  18. Procedure do_out;  (* To PIC *)
  19. Var
  20.   DCS : DPMIRegisters;
  21.   selseg, selseg_buff :longint;
  22.   selector, selector_buff, segment, segment_buff : word;
  23.   P_PM : p_buffer;
  24.   P_PM_buff : p_buffer;
  26. Begin
  27. selseg := globaldosalloc(40);
  28. selector := word(selseg and $FFFF);
  29. segment := word(selseg SHR 16);
  30. P_PM:=ptr(selector,0);
  32. selseg_buff := globaldosalloc(257);
  33. selector_buff := word(selseg_buff and $FFFF);
  34. segment_buff := word(selseg_buff SHR 16);
  35. P_PM_buff:=ptr(selector_buff,0);
  36. move(buffer_o,P_PM_Buff^,sizeof(buffer_o)); (*REMPLISSAGE AVEC POINTEUR PROTECTED VERS MEMOIRE AVEC DONNEES MODE REEL *)
  38. (* set up out request *)
  39. urb.transaction_token := $E1;(* $E1= Sortie*)
  40. urb.chain_end_flag := 0;
  41. urb.dev_add := the_dev_add;  (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
  42. urb.end_point := out_endpoint;    (* =1 *)
  43. urb.error_code := 0;
  44. urb.status := 0;
  45. urb.transaction_flags := 0;
  46. urb.buffer_off :=0; (* METTRE OFFSET A 0 *)
  47. urb.buffer_seg := segment_buff; (* SEGMENT ADRESSE EN MODE REEL *)
  48. urb.buffer_length := packetlen;
  49. urb.actual_length := 64;
  50. urb.setup_buffer_off := 0;
  51. urb.setup_buffer_seg := 0;
  52. urb.start_frame := 0;
  53. urb.nr_of_packets := 0;
  54. urb.int_interval := 0;
  55. urb.error_count := 0;
  56. urb.timeout := 0;
  57. urb.next_urb_off := 0;
  58. urb.next_urb_seg := 0;
  60. (* now call DosUHCI *)
  61. fillchar(dcs, sizeof(dcs), 0);
  62. move(urb,P_PM^,sizeof(urb)); (*REMPLISSAGE AVEC POINTEUR PROTECTED VERS MEMOIRE AVEC DONNEES MODE REEL *)
  63. DCS.DPMI_ES := 0;(*segment;*)
  64. DCS.DPMI_DS := segment;(*ADRESSE SEGMENT MODE REEL DE MA STRUCTURE URB*)
  65. DCS.DPMI_EDX := 0;
  66. intr386($65, 0, dcs);
  67. GlobalDosFree(selector);
  68. GlobalDosFree(selector_buff);
  69. (* Reg.DS := seg(urb);
  70. Reg.DX := ofs(urb);
  71. Intr($65,Reg);*)
  72. Inc(ReqNr);
  73. End (* do_out *);

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed