Ignorer un Get si aucune valeur entré

Marsh Posté le 05-12-2011 à 11:38:05

Bonjour, je fait actuellement un programme en ada et j'aimerais qu'un de mes Get_Immediate soit ignoré si je ne tape pas la bonne touche (ici un 'a').

Exemple :

début de mon programme;
Get_Immediate (X);
if X = 'a' then
faire ce que je veux;
end if;
suite de mon programme;

Je veux que si je ne tape rien ou une autre touche que 'a', je passe directement a la suite de mon programme.

J'ai vu sur internet quelque chose avec des TASK mais je n'ai pas tout compris.

Merci pour vos futures réponses.

Reply

Marsh Posté le 05-12-2011 à 11:38:05

Reply

Marsh Posté le 05-12-2011 à 13:08:40

Bonjour,

Voici un code qui te permet de poursuivre le traitement à défaut de l'exécution d'un get, mais le get sera de toute manière engager jusqu'à ce qu'un caractère soit entré.

Code :

with Text_Io;
use Text_Io;
procedure Main is
 
   task type Process_Type is
   end Process_Type;
 
   task type Console_Type is
      entry Send(Char : out Character);
   end Console_Type;
 
   task body Console_Type is
      The_Char : Character;
   begin
      Get_Immediate(The_Char);
      accept Send(Char : out Character) do
         Char := The_Char;
      end Send;
   end Console_Type;
 
   task body Process_Type is
 
      Console : Console_Type;
      Char : Character;
   begin
      select
         Console.Send(Char);
         -- travailler avec le Char
      or
         delay 2.0;
         -- ou faire autre chose.
      end select;
      Put_line("Suite du process" );
 
   end Process_Type;
 
   My_Process : Process_Type;
begin
 
   null;
end Main;

Message édité par Profil supprimé le 05-12-2011 à 13:24:49

Reply

Marsh Posté le 05-12-2011 à 18:50:27

Merci beaucoup.
Par contre, j'ai mis le SELECT dans une boucle et du coup quand je lance mon prog, il tourne, puis je tape la touche, il fait l'action désirée, puis il s’arrête.
C'est du a la boucle ou autre chose ?

Reply

Marsh Posté le 06-12-2011 à 07:16:14

Comme ça, je peux pas te dire, il faudrait que tu montre le reste de ton code.

Message édité par Profil supprimé le 06-12-2011 à 07:16:41

Reply

Marsh Posté le 06-12-2011 à 07:58:16

Si tu souhaite saisir plusieurs caractères, je te propose ce code, qui réserve un caractère, ici nul, qui, en boucle est renvoyé si rien n'est saisi et travaille avec le caractère saisie dans le cas contraire.

Code :

with Text_Io;
use Text_Io;
procedure Main is
 
   task type Process_Type is
      entry Get_Char(The_Char : out Character);
   end Process_Type;
 
   task type Console_Type is
      entry Send(Char : out Character);
   end Console_Type;
 
   task body Console_Type is
      The_Char : Character;
   begin
      loop
         Get_Immediate(The_Char);
         accept Send(Char : out Character) do
            Char := The_Char;
         end Send;
      end loop;
   end Console_Type;
 
   task body Process_Type is
 
      Console : Console_Type;
      Char : Character;
   begin
      loop
         select
            Console.Send(Char);
            accept Get_Char(The_Char : out Character) do
               The_Char := Char;
            end Get_Char;
         or
            delay 2.0;
            accept Get_Char(The_Char : out Character) do
               The_Char := Character'Val(0);
            end Get_Char;
         end select;
      end loop;
   end Process_Type;
 
   My_Process : Process_Type;
   Char : Character;
begin
 
   loop
      My_Process.Get_Char(Char);
      if char /= Character'Val(0) then
 
         Put_Line("travailler avec le char" );
      else
 
         Put_Line("travailler sans le char" );
      end if;
   end loop;
end Main;

Message édité par Profil supprimé le 06-12-2011 à 08:01:17

Reply

Marsh Posté le 06-12-2011 à 16:21:53

Ok, et bien merci beaucoup pour tout ça, ça m'aide beaucoup !

Reply

Marsh Posté le 06-12-2011 à 19:00:48

Avec plaisir.

Reply

Ignorer un Get si aucune valeur entré

Sujets relatifs:

Leave a Replay